RegionFunction with a parametric curve

Question

I would like to produce contour and density plots for a known function of x and y for x>=0 and y>=0. The function has a singularity curve in the x-y plane and I only want to evaluate the function inside that curve.  However, the curve is known only parametrically so it is not clear to me how to use RegionFunction. Suggestions?

Ulrich Neumann · Answer

Assuming examplary function(singularity)
f[x_]:= ((3/4 - x/2)/(1/2 + x))  
reg = ImplicitRegion[x >= 0 && y >= 0 && y <= f[x], {x, y}]
RegionPlot[reg]

ContourPlot[ ... , Element[{x,y},reg]] restricts your plots to the region reg

Michael E2 · Answer

Perhaps this?:
reg = BoundaryDiscretizeGraphics@
  ParametricPlot[{Exp[Cos[t]], Log[2 + Sin[t]]}, {t, 0, 2 Pi}]

ContourPlot[Sin[x] Cos[2 x y], {x, y} [Element] reg]

Alternative:
ContourPlot[Sin[x] Cos[2 x y],
 {x, 0, 3}, {y, 0, 2},
 RegionFunction -> Function[{x, y}, RegionMember[reg, {x, y}]]
 ]

cvgmt · Answer

It seems that the question is how to construct a region by some curves.(Thanks @Michael E2 provide a function and an example).
Here is one way.
f[t_] := {Cos[t], Sin[t]}; 
reg = 
 ParametricRegion[{0, 0} + s*f[t], {{t, 0, π/2}, {s, 0, 1}}];
DensityPlot[Sin[x] Cos[2 x y], {x, y} ∈ reg]

RegionFunction with a parametric curve

3 Answers

Add your own answers!

Ask a Question