Dedicated image - but dedicated to what/who?

Following Leppy's lead, here's an animated .gif with all the layers in order of hue.

The 19 colors themselves are fully-saturated and evenly spaced around the edge of the color wheel, suggesting a kind of sequence.

Numbering the colors from 0 (red) to 18 (magenta) we have the following numbers of pixels of each color:

Taking each one of these numbers mod 26:

Converting these numbers into letters (1 to A and 26 to Z) gets us:

...the name of a song by:

---

Mathematica code to solve the puzzle:

FromCharacterCode[
 Mod[Last /@ 
    SortBy[Tally[
      Join @@ Import["http://i.stack.imgur.com/feRTC.gif", 
        "RGBColorArray"]], First@ColorConvert[First@#, "HSB"] &], 
   26] + 64]

...and to generate similar puzzles:

message = "ITSAWONDERFULLIFE";
cover = "HomagentonJS";
n = StringLength[message];
colors = Round[List @@@ ColorConvert[Hue /@ (5/6 Rescale@Range@n), "RGB"], 1/255];
counts = ToCharacterCode[message] - 64;
{w, h} = Catch[Do[
           If[Mod[w h - Total[counts], 26] == 0, Throw[{w, h}]],
           {w, 300, 500}, {h, w - 2, w + 2}
         ]];
data = Rasterize[
         Row[Style[#, RGBColor @@ RandomChoice@colors, Bold] & /@ Characters@cover],
         "Data", ImageSize -> {w, h}
       ] /. Append[Thread[255 colors -> Range[n]], {_, _, _} -> 0];
counts = Mod[counts - BinCounts[Join @@ data, {1, n + 1, 1}], 26];
zeros = Count[data, 0, {2}] - Total[counts];
counts += RandomSample@First@IntegerPartitions[zeros, {n}, Floor[zeros/n, 26]+{0, 26}, 1];
random = RandomSample[Join @@ MapThread[ConstantArray, {Range[n], counts}]];
i = 1;
data = data /. {0 :> random[[i++]]};
img = Image[data /. Thread[Range[n] -> colors]]