AMPScript IF statement or Loop?

General pointer: Don't use IF / ELSEIF / ELSE here. This will only process one leg of the IF-statement so you cannot combine multiple. In other words: It's "either/or".

Solution 1)

You don't need "either/or", you need: "maybe A and maybe B and maybe C"

So: Just chain IFs.

Translated to pseudocode:

IF A THEN ... ENDIF; 
IF B THEN ...ENDIF; 
IF C THEN ...ENDIF;

Very simple, but very dumb, not elegant at all, hard to scale.

var @Subkey, @EmailAddress, @FirstName, @Event_ID, @Event_Name 

Set @Subkey = Subscriberkey 
Set @EmailAddress = EmailAddress
Set @FirstName = FirstName
Set @Event_ID = Lookup('event','Event_ID','Email_address',@EmailAddress)
Set @Event_name = Lookup('Event detail', 'Event_Name', 'Event_ID', @Event_ID)

]%%

Hello %%= v(@FirstName)=%%<br>
Thansk for watching %%= v(@Event_Name)=%%<br>

Here are more content you might be interested in<br>

%%[
IF @Event_ID == '12345' THEN 
]%%

    THANKS FOR WATCHING WEBINAR A 

%%[
ENDIF
IF @Event_ID == '54321' THEN 
]%%

    THANKS FOR WATCHING WEBINAR B 

%%[
ENDIF
IF @Event_ID == 'webinarC' THEN ]%%

    THANKS FOR WATCHING WEBINAR C
                
    Thank you 

%%[
ENDIF
]%%

Solution 2:

for loop. The "right" way to do this, short and concise, scales automatically with more records per person in your "event" table.

%%[ 
SET @EmailAddress = EmailAddress
Set @allAttendedEventsAsRowset = LookupRows('event','Email_address',@EmailAddress)
SET @rowCount = rowcount(@allAttendedEventsAsRowset)
 
IF @rowCount > 0 THEN
 
  FOR @i = 1 TO @rowCount DO
 
    SET @row = row(@allAttendedEventsAsRowset,@i) /*get row based on loop counter */
    SET @eventID = field(@row,'Event_ID')
    SET @eventName = Lookup('Event detail', 'Event_Name', 'Event_ID', @eventID)

]%%

THANKS FOR WATCHING %%=v(@eventName)=%%

%%[
 
  NEXT @i
 
ENDIF
]%% 

Code is from memory. Should work, but no guarantee. Hope it helps!

I have slightly updated conditions that you have used, you can try out the below script and if it works make sure to mark as answered so this might help someone down the road.

%%[ var @Subkey, @EmailAddress, @FirstName, @Event_ID, @Event_Name

Set @Subkey =Subscriberkey 
Set @EmailAddress = EmailAddress 
Set @FirstName = FirstName 
Set @Event_ID = Lookup('event','Event_ID','Email_address',@EmailAddress) 
Set @Event_name = Lookup('Event detail', 'Event_Name', 'Event_ID', @Event_ID)

]%%


Hello %%= v(@FirstName)=%%
Thansk for watching %%= v(@Event_Name)=%%

Here are more content you might be interested in

%%[IF @Event_ID == '12345' THEN]%% THANKS FOR WATCHING WEBINAR A

%%[ELSEIF @Event_ID == '54321' THEN]%% THANKS FOR WATCHING WEBINAR B

%%[ELSEIF @Event_ID != '12345' or @Event_ID != '54321' THEN]%% THANKS FOR WATCHING WEBINAR C

%%[ENDIF]%%